/* A scanner that will extract email addresses, most URLs, and some
     forms of bank account information from a text stream (e.g. a list
     of  emails). This is for pedagogical purposes only ;-).
     
     
     Domain name syntax according to RFC 1034
     
     <domain> ::= <subdomain> | " "
     
     <subdomain> ::= <label> | <subdomain> "." <label>
     
     <label> ::= <letter> [ [ <ldh-str> ] <let-dig> ]
     
     <ldh-str> ::= <let-dig-hyp> | <let-dig-hyp> <ldh-str>
     
     <let-dig-hyp> ::= <let-dig> | "-"
     
     <let-dig> ::= <letter> | <digit>
     
     <letter> ::= any one of the 52 alphabetic characters A through Z in
     upper case and a through z in lower case
     
     <digit> ::= any one of the ten digits 0 through 9   
  */

%option noyywrap

DIGIT     [0-9]
LETTER    [A-Za-z]
LETDIG    {DIGIT}|{LETTER}
LETDIGHYP {LETDIG}|-
LDHSTR    {LETDIGHYP}+
LABEL     {LETTER}({LDHSTR}*{LETDIG})*
SUBDOMAIN {LABEL}(\.{LABEL})*
NAME      [A-Za-z0-9_.~-]+

EMAIL     {NAME}@{SUBDOMAIN}
PATHCHAR  {LETDIG}|[-_.~]
SIMPLEURL http:[/][/]{SUBDOMAIN}(:{DIGIT}+)?([/]{PATHCHAR}+)* 

ACTID     Konto|Kto|KNr|Ktonr|Kontonummer
OLDACCOUNT {ACTID}[.]?[:]?[ ]*{DIGIT}{1,10}

DECIBAN   DE{DIGIT}{20}
DEHIBAN   DE{DIGIT}{2}([ ]{DIGIT}{4}){4}[ ]{DIGIT}{2}
DEIBAN    {DECIBAN}|{DEHIBAN}

ACCOUNT   {DEIBAN}|{OLDACCOUNT}


%%

{EMAIL} {
   printf("Found email: %s\n", yytext);
   }

{SIMPLEURL} {
   printf("Found url: %s\n", yytext);
   }  


{ACCOUNT} {
   printf("Found account: %s\n", yytext);
   }  


\n|. { 
        /* printf("Skip\n"); */
      }
%%

int main( int argc, char **argv )       
{
   ++argv, --argc;  /* skip over program name */
   if ( argc > 0 )
      yyin = fopen( argv[0], "r" );
   else
      yyin = stdin;
   
   yylex();
   
   fclose(yyin);
}